{
    description = "Project Tool";

    inputs = {
        nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
        flake-utils.url = "github:numtide/flake-utils";
        rust-overlay = {
            url = "github:oxalica/rust-overlay";
            inputs.nixpkgs.follows = "nixpkgs";
        };
    };

    outputs = { nixpkgs, flake-utils, rust-overlay, ... }:
        flake-utils.lib.eachDefaultSystem (system:
            let
                overlays = [ (import rust-overlay) ];
                pkgs = import nixpkgs { inherit system overlays; };
                lib = nixpkgs.lib;
                rust = pkgs.rust-bin;

                rustToolchain = rust.fromRustupToolchainFile ./rust-toolchain.toml;
                rustNightlyToolchain = rust.selectLatestNightlyWith (t: t.minimal.override {
                    extensions = [ "rustfmt" ];
                });
                rustPlatform = pkgs.makeRustPlatform {
                    cargo = rustToolchain;
                    rustc = rustToolchain;
                };

                buildTools = [
                    rustToolchain
                    rustNightlyToolchain
                ];

                manifest = lib.importTOML ./Cargo.toml;
                packageName = manifest.package.name;
                packageVersion = manifest.package.version;

                package = rustPlatform.buildRustPackage {
                    nativeBuildInputs = buildTools;

                    pname = packageName;
                    version = packageVersion;
                    src = lib.cleanSource ./.;

                    verbose = true;

                    cargoLock = {
                        lockFile = ./Cargo.lock;
                        allowBuiltinFetchGit = true;
                    };

                    meta = {
                        mainProgram = packageName;
                    };
                };
            in {
                packages = {
                    default = package;
                    ${packageName} = package;
                };

                devShells.default = pkgs.mkShell {
                    name = "projtool";

                    nativeBuildInputs = buildTools;
                };
            });
}